REM This scripts shows steps that needs to be done to compile debea library 
REM from svn sources using VC nmake tool.

REM It generates dsp/dsw projects for VC. If you want to use them you need 
REM to setup following enviroment variables:
REM DEVEL - for finding headers of installed libraries
REM CPPUNIT - where cppunit library is installed

REM Variables below are needed to compile database plugins

REM Native sqlite3 support:
REM SQLITE3_PATH - path to headers and libs of sqlite3 library.

REM Native PostgreSQL support:
REM POSTGRESQL - path to postgres 8.x is installed 

REM To compile wxdba library:
REM WXWIN - place where wxWidgets library is installed

REM see presets/syslibs.bkl <sqlite3> and <postgres> template to see how those 
REM variables are used.

REM Please do not modify this script. If you want to pass different paths or
REM build diffrent plugins please modify a copy of it.

REM dir where sources are unpacked
SET SOURCES_DIR=C:\sources\debea

REM plugins to build (passed to configure)
SET DBA_PLUGINS=CSV=1 SQLITE3=1 ODBC=1 PGSQL=1 XML=1

REM place where libraries should be installed
SET DEVEL=C:\devel\debea

REM configure flags for all libraries
SET DEBEA_CONFIGURE_FLAGS=DEBUG=1 TESTS=1

REM place where libraries should be build
SET BUILD_DIR=C:\build\debea

REM bakefile_gen run from Makefile.cvs needs to find additional files:
REM syslibs.bkl and baseprj.bkl from "presets" dir and presets generated by each library
REM remember that bakefile appends 'presets' subdir to each path component
SET BAKEFILE_PATHS=%DEVEL%\share\bakefile;%SOURCES_DIR%

REM let configure find common-config and dba-config where debea is supposed to be installed
REM we append dba build dir because regression tests needs to find plugins to run.
PATH=%PATH%;%DEVEL%\bin:%BUILD_DIR%\dba

REM create project files for dba library
cd %SOURCES_DIR%\dba
bakefile_gen -f msvc,msvc6prj -d dba.bkgen
IF %ERRORLEVEL% NEQ 0 GOTO ERROR

REM setup MSVC tools
if not "%VS90COMNTOOLS%"=="" ( call "%VS90COMNTOOLS%vsvars32.bat"
) else ( if not "%VS80COMNTOOLS%"=="" ( call "%VS80COMNTOOLS%vsvars32.bat"
) else ( if not "%VS71COMNTOOLS%"=="" call "%VS71COMNTOOLS%vsvars32.bat" ) )

REM build dba library.
nmake /f makefile.vc %DEBEA_CONFIGURE_FLAGS% %DBA_PLUGINS%
IF %ERRORLEVEL% NEQ 0 GOTO ERROR
nmake /f makefile.vc %DEBEA_CONFIGURE_FLAGS% %DBA_PLUGINS% check
IF %ERRORLEVEL% NEQ 0 GOTO ERROR
nmake /f makefile.vc %DEBEA_CONFIGURE_FLAGS% %DBA_PLUGINS% install
IF %ERRORLEVEL% NEQ 0 GOTO ERROR

REM create project files wxdba library
cd %SOURCES_DIR%\wxdba
bakefile -f msvc wxdba.bkl
bakefile -f msvc6prj wxdba.bkl
IF %ERRORLEVEL% NEQ 0 GOTO ERROR

REM build wxdba library - needs wxWidgets to build
nmake /f makefile.vc %DEBEA_CONFIGURE_FLAGS%
IF %ERRORLEVEL% NEQ 0 GOTO ERROR
nmake /f makefile.vc %DEBEA_CONFIGURE_FLAGS% check
IF %ERRORLEVEL% NEQ 0 GOTO ERROR
nmake /f makefile.vc %DEBEA_CONFIGURE_FLAGS% install
IF %ERRORLEVEL% NEQ 0 GOTO ERROR

cd ..
@echo ======================
@echo Success!
@echo C++ Headers installed in %DEVEL%\include
@echo Libraries installed in %DEVEL%\lib
@echo Plugins installed in %DEVEL%\lib\plugins(d)
@echo ======================
GOTO END

:ERROR
@echo ======================
@echo ERROR occured
@echo Please check http://debea.net/trac/report/3
@echo And report if this problem is not already there
@echo ======================

:END